Macro  calib_compare

KUIP/SET_SHOW/FILECASE KEEP
mess PAW:: use file1 $ENV(paw_arg1)
mess PAW:: use file2 $ENV(paw_arg2)
mess PAW:: use file3 $ENV(paw_arg3)
mess PAW:: use RUNNUM $ENV(paw_arg4)

file1=$ENV(paw_arg1)
file2=$ENV(paw_arg2)
file3=$ENV(paw_arg3)
run=$ENV(paw_arg4)

*size 20 30 
size 21 27

zon 1 4
opt nbox
opt date
opt grid
*------------
set GFON -42 
set VFON -42 
set LFON -42
set CFON -42 
set TFON -42 
*
set HWID 2 
set FWID 2 
set BWID 2 
set PWID 2 
*------------

title 'Calib-Ped-Run='//[run]//'  '//[file3]

For/File  1  [file3]
Metafile -1   -111

ve/read a [file1]
ve/read b [file2]
vsub a b c 
dima=$VDIM(a,1)
dimb=$VDIM(b,1)
dimc=$VDIM(c,1)

HISTOGRAM/CREATE/1DHISTO 110 'Ped Diff (new-old)' 21 -10.5 +10.5
HISTOGRAM/CREATE/1DHISTO 111 'Ped New' 100 0 4100
HISTOGRAM/CREATE/1DHISTO 112 'Ped Old ' 100 0 4100


VECTOR/HFILL c 110
VECTOR/HFILL a 111
VECTOR/HFILL b 112

opt nsta
*ve/draw Ped 100

HISTOGRAM/CREATE/1DHISTO 101 'Ped New' [dima] 0 [dima]
HISTOGRAM/PUT_VECT/CONTENTS 101 a
min   101 0 
max   101 4100
hi/pl 101

HISTOGRAM/CREATE/1DHISTO 102 'Ped Old' [dimb] 0 [dimb]
HISTOGRAM/PUT_VECT/CONTENTS 102 b
min   102 0
max   102 4100
hi/pl 102

HISTOGRAM/CREATE/1DHISTO 100 'Ped Diff (new-old) ' [dimc] 0 [dimc]
HISTOGRAM/PUT_VECT/CONTENTS 100 c
min  100 -10
max  100  10
hi/pl 100

opt stat
set stat 111111
opt fit

zon 3 4 10 s
hi/pl 111
hi/pl 112
*hi/pl 110

*ve/cre par(3) r 

hi/fit 110 g 

*do i=1,[dimc]
*   mess i=[i]=[c([i])]
*enddo

close 1

return