#!/bin/csh


# Use the .setup file in the coda directory to setup the core
# CODA environment. We need to set a few values first though
# and save the setting of EXPID. (The .setup file may overwrite
# some of these.)

# For cleanliness, first try and remove previous CODA settings from
# various PATHS
if ( $?CODA ) then
	if ( $?CODA_BIN     ) then
		filter_path PATH ${CODA_BIN}
	endif
	if ( $?CLASSPATH    ) then
		filter_path CLASSPATH "$CODA/common/jar/*"
	endif
	if ( $?CODA_LIB     ) then
		filter_path LD_LIBRARY_PATH ${CODA_LIB}
	endif
	if ( $?CODA_VME_LIB ) then
		filter_path LD_LIBRARY_PATH ${CODA_VME_LIB}
	endif
endif


# Set some initial variables that the .setup may want to overwrite
setenv CODA              /gluex/coda/3.06
setenv CODA_ARCH         $CODA/`uname -s`-`uname -p`

setenv LINUXVME_INC      $CODA/linuxvme/include
setenv LINUXVME_LIB      $CODA/linuxvme/lib

# Double quotes required here (see svn log -r12581)
setenv CLASSPATH         "$CODA/common/jar/*:${CLASSPATH}"

# Save EXPID if it is set
if ( $?EXPID ) then
	setenv EXPID_SAVE $EXPID
else
	setenv EXPID_SAVE __none__
endif

#-----------------------------------------------------
# Source the .setup file in the CODA distribution directory
if ( -e ${CODA}/.setup ) then
	source ${CODA}/.setup
else
	echo "File: $CODA/.setup does not exist!"
endif
#-----------------------------------------------------

# Restore EXPID if it was set before
if ( $EXPID_SAVE != "__none__" ) then
	setenv EXPID $EXPID_SAVE
endif
unsetenv EXPID_SAVE


# needed by online build system
setenv CMSGROOT          $CODA_ARCH
setenv EVIOROOT          $CODA_ARCH
setenv ETROOT            $CODA_ARCH
setenv CODAOBJECTROOT    $CODA_ARCH



# Cleanup some path environment variables to remove duplicate
# and empty entries
filter_path PATH
filter_path LD_LIBRARY_PATH
filter_path CLASSPATH
filter_path PYTHONPATH