#!/bin/tcsh
#
# This file should be sourced by your existing shell
# to setup your environment. 
#

if ( -e /gapps/root/${BMS_OSNAME}/5.34.26/bin/thisroot.csh ) then

	# Remove all other gcc versions from PATHs
	while ( `which root` != 'root: Command not found.' )
		set loc=`which root`
		set bindir=`dirname $loc`
		set rootsys=`dirname $bindir`
		set libdir=$rootsys/lib
		set mandir=$rootsys/man
		if ($?loginsh ) echo "Removing $rootsys"
		filter_path PATH $bindir
		filter_path LD_LIBRARY_PATH $libdir
		filter_path PYTHONPATH $libdir
		filter_path MANPATH $mandir
	end

	# Could not get thisroot.csh to work properly with
	# the setup system. Setup environment manually

	setenv ROOTSYS /gapps/root/${BMS_OSNAME}/5.34.26
	setenv PATH ${ROOTSYS}/bin:${PATH}

	if ($?LD_LIBRARY_PATH) then
   	setenv LD_LIBRARY_PATH $ROOTSYS/lib:$LD_LIBRARY_PATH
	else
   	setenv LD_LIBRARY_PATH $ROOTSYS/lib
	endif

	if ($?PYTHONPATH) then
   	setenv PYTHONPATH $ROOTSYS/lib:$PYTHONPATH
	else
   	setenv PYTHONPATH $ROOTSYS/lib
	endif

	if ($?MANPATH) then
   	setenv MANPATH $ROOTSYS/man:$MANPATH
	else
   	setenv MANPATH $ROOTSYS/man
	endif


	filter_path PATH
	filter_path LD_LIBRARY_PATH

else
	if ( $?loginsh ) echo "root-5.34.26 not available for $BMS_OSNAME"
endif